#Encoding W
#DefColor 27= 0x000000
#DefColor 35= 0xFFFFFF
#DefColor 36= 0,255,0 .. 44=255,0,0
#DefColor 40= 220 220 220

#DefStyle common
	#Slide.Background= 40 7 7 40 bidir
	#Slide.GradMaxSize= 2
	#XAxis.Visible off
	#YAxis.Visible off
	#TextInner.IndentHoriz 8
	#TextInner.IndentVert 4
	#VGrid -1
	#HGrid -1
	#ExtraX 15
	#ExtraY 10
	#ShowTN always
	##Title.Visible off
	#Title.Border 0 0 0 1
	##Title.BorderColor 7
	#Title.Justify left
#EndStyle

#######################################################################
#NewSlide C
#Title Слайд 1 из 10      Свойство C: цвет точки
#Slide.Style common

#Let real x= int (RowIndex mod 9)
#Let real y= int (-RowIndex / 9)
#Let real tc= if (@=0 or @=3 or @=14 or @>19 and @<32, 7, 0)
#Let text ti= "C=[RowIndex]"

#Series X=x Y=y C=RowIndex TC=tc S=2 TI=ti
#SeriesSize 45

#TitleBelow Примечание: цвета 27..44 определены командой DefColor

#######################################################################
#NewSlide S
#Title Слайд 2 из 10      Свойство S: форма точки
#Slide.Style common
#ExtraX 10, 20
#ExtraY 4
#AutoScaleX max

#Let real x= int ((RowIndex-1) mod 4)
#Let real y= int (-(RowIndex-1) / 4)
#Let text tn= "S=[RowIndex]"

#Series X=x Y=y W=15 S=RowIndex TN=tn C=1
#SeriesSize 41

#######################################################################
#NewSlide S-W
#Title Слайд 3 из 10      Свойства S и W: форма и размер 
#Slide.Style common
#ExtraX 5, 10
#ExtraY 15
#AutoScaleX off

#Let real s= int (RowIndex mod 10) + 1
#Let real w= int (RowIndex/10) * 4 + 6
#Let real y= -int(RowIndex/10)
#Let text tn= "S=[s]\nW=[w]"

#Series X=s Y=y S=s W=w TN=tn C=13
#SeriesSize 30

##DumpFile foo
##DumpData "[s]\t[w]\t[y]"

#######################################################################
#NewSlide S-TI
#Title Слайд 4 из 10      Свойства S и W: точки с текстом TI
#Slide.Style common
#ExtraX 5, 10
#ExtraY 15
#AutoScaleX off

#Let real s= int (RowIndex mod 10) + 1
#Let real w= int (RowIndex/10) * 4 + 1
#Let real y= -int(RowIndex/10)
#Let text ti= "S=[s]\nW=[w]"

#TextInner.IndentHoriz 2
#TextInner.IndentVert 2
#Series X=s Y=y S=s W=w TI=ti C=13
#SeriesSize 30

##DumpFile foo
##DumpData "[s]\t[w]\t[y]"

#######################################################################
#NewSlide MS
#Title Слайд 5 из 10      Свойство MS: стиль свечи
#Slide.Style common
#CandleWidth 1
#PoseTN up

#Let real t= RowIndex mod 3
#Let byte ms= RowIndex / 3 + 1
#Let byte oc= ms+20
#Let real x= RowIndex + ms*3
#Let real mc= 20 + 5 * sin(5+6*t*t)
#Let real mh= mc + 1.1 + sin(t*137)
#Let real ml= mc - 2.5 + sin(t*87)
#Let real mo= mc + 1.1 * sin(2+t*t*4)
#Let text tn= if (t=0, "MS=[ms]", "")

#Series X=x MO=mo MC=mc MH=mh ML=ml MS=ms TN=tn TR=tn C=7 G=0 O=oc LW=0
#SeriesSize 15

#######################################################################
#NewSlide LS
#Title Слайд 6 из 10      Свойство LS: стиль линии
#Slide.Style common
#AutoScaleX off
#ExtraX 10, 30

#Let real y= -RowIndex
#Let text tn= "LS=[RowIndex]"

#Series X=0 Y=y W=5 S=3 C=4 LD=2 LC=1 LS=RowIndex
#Series X=1 Y=y W=5 S=3 C=4 TN=tn
#SeriesSize 5

#######################################################################
#NewSlide LP
#Title Слайд 7 из 10      Свойство LP: форма пути линии
#Slide.Style common
#AutoScaleX off
#ExtraX 5, 10

#Let real lp= RowIndex+1
#Let real x1= int (RowIndex mod 3) - 0.3
#Let real y1= int (-RowIndex / 3) - 0.3
#Let real x2= int (RowIndex mod 3) + 0.3
#Let real y2= int (-RowIndex / 3) + 0.3
#Let text tn= "LP=[lp]"

#Series X=x1 Y=y1 W=5 S=3 C=4 LP=lp LD=2 LC=1 LA=1
#SeriesSize 6
#Series X=x2 Y=y2 W=5 S=3 C=4 TN=tn
#SeriesSize 6

#NewData sx, sy, sw, slp
#Let text stn= if(RowIndex=2,"LP=7","")
#Series X=sx Y=sy W=sw S=3 C=4 LP=slp LC=1 LA=1 TN=stn U=16
-0.5	0	0	0
0.5	-2.3	5	7
1.5	-1.7	5	0
2.5	-4	0	0
#AutoScaleY max

##DumpFile foo
##DumpData "([x1], [y1])  ([x2], [y2])"

#######################################################################
#NewSlide LA
#Title Слайд 8 из 10      Свойство LA: тип стрелок
#Slide.Style common
#AutoScaleX off
#ExtraX 10, 30

#Let real y= -RowIndex
#Let text tn= "LA=[RowIndex]"

#Series X=0 Y=y W=5 S=3 C=4 LD=2 LC=1 LA=RowIndex
#Series X=1 Y=y W=5 S=3 C=4 TN=tn
#SeriesSize 4

#######################################################################
#NewSlide FS
#Title Слайд 9 из 10      Свойство FS: форма заливки
#Slide.Style common
#AutoScaleX off
#ExtraX 10, 30
#ExtraY 5

#Let real y= -RowIndex
#Let real yf= -RowIndex+0.5
#Let text tn= "FS=[RowIndex]"

#Series X=0 Y=y W=5 S=3 C=4
#Series X=1 Y=y W=5 S=3 C=4 TN=tn
#SeriesSize 6

#Series X=0 Y=yf W=0 LC=1 LW=0 FD=1 FC=13 FS=RowIndex
#Series X=1 Y=yf W=0 
#SeriesSize 7

#######################################################################
#NewSlide FD
#NewPanel Head: text
#Head Слайд 10 из 10      Свойство FD: направление заливки
#Head.FontStyle title
#Head.Justify left
#Head.Border 0 0 0 1
#Slide.Background= 40 7 7 40 bidir
#Slide.GradMaxSize= 2
#NewData x, y
1	1
2	3
3	2
4	4
#Let ymin = y-1
#Let ymax = y+1

#DefStyle FDsty
	#XAxis.Visible off
	#YAxis.Visible off
	#VGrid -1
	#HGrid -1
	#ExtraX 5, 60
	#ExtraY 4
	#ShowTN last
	#Series smin: X=x Y=ymin W=5 S=3 C=4 LC=1
	#Series s:    X=x Y=y W=7 S=3 C=4 LC=1 LW=2 FC=10
	##Series s:    X=x Y=y W=7 S=3 C=4 LC=1 LW=2 FC=10 LP=3 FP=3 
	#Series smax: X=x Y=ymax W=5 S=3 C=4 LC=1
#EndStyle

#NewPanel FD1
#YAxis.MinWidth 10
#Slide.Style FDsty
#SeriesModify s: FD=1 TN=FD=1

#NewPanel FD2
#Slide.Style FDsty
#SeriesModify s: FD=2 TN=FD=2

#NewPanel FD3
#Slide.Style FDsty
#SeriesModify s: FD=3 TN=FD=3

#NewPanel FD4
#Slide.Style FDsty
#SeriesModify s: FD=4 TN=FD=4

#NewPanel FD5
#Slide.Style FDsty
#SeriesModify s: FD=5 TN=FD=5

#NewPanel FD6
#Slide.Style FDsty
#SeriesModify s: FD=6 TN=FD=6

#NewPanel FD7
#Slide.Style FDsty
#SeriesModify s: FD=7 TN=FD=7

#NewPanel FD8
#Slide.Style FDsty
#SeriesModify s: FD=8 TN=FD=8

#Group (1,1)(1,1,1,1) FDS= FD1, FD2, FD3, FD4, FD5, FD6, FD7, FD8
#Group (0,1)(1) all= Head, FDS

#######################################################################
#Slide <<
